Gradle如何将aar发布至Jcenter

     buildscript {//配置gradle编译环境
         repositories {
             jcenter()
         }
         dependencies {
             classpath 'com.android.tools.build:gradle:2.2.3' 
             //需要github插件，github上传即可打包至jcenter
             classpath 'com.github.dcendents:android-maven-gradle-plugin:1.4.1'
             //jcenter资源包，允许脚本发布至Jcenter
             classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.5' 
         }
     }
     allprojects {
         repositories {
             jcenter()
         }
     }
   

       //声明打包需要用到的插件
       apply plugin: 'com.android.library'
       apply plugin: 'com.github.dcendents.android-maven'
       apply plugin: 'com.jfrog.bintray'
       //android module配置
       android {
           compileSdkVersion 19
           buildToolsVersion "24.0.0"
           sourceSets {//指定gradle源码识别目录
               main {
                   manifest.srcFile 'AndroidManifest.xml'
                   java.srcDirs = ['src']
                   resources.srcDirs = ['src']
                   aidl.srcDirs = ['src']
                   renderscript.srcDirs = ['src']
                   res.srcDirs = ['res']
                   assets.srcDirs = ['assets']
               }       
           }
       }
       
       buildscript {
           repositories {
               jcenter()
           }
           dependencies {
               classpath 'com.android.tools.build:gradle:2.2.3'
           }
       }
       
       dependencies {
           compile fileTree(include: '*.jar', dir: 'libs')
       }
       
        // 项目的主页，改为自己的github主页地址
       def siteUrl = 'https://github.com/xx/xx'     
        // Git仓库的url,，改为自己的github 代码地址
       def gitUrl = 'https://github.com/xx/xx.git'  
       // Maven Group ID for the artifact，一般填你唯一的包名
       group = "com.your.package" 
       //项目引用版本号 artifactId,在此配置，更新时修改次版本号
       version = "1.0.2"
       //maven仓库配置
       install {
           repositories.mavenInstaller {
               pom {
                   project {
                       packaging 'aar'//打包方式
                       	//项目描述
                       name 'biu biu biu biu' 
                       url siteUrl

                       licenses {
                           license {
                               name 'The Apache Software License, Version 2.0'
                               url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                           }
                       }
                       developers {
                           developer { //开发者信息
                               id ''		//填写的一些基本信息
                               name ''
                               email ''
                           }
                       }
                       scm {
                           connection gitUrl
                           developerConnection gitUrl
                           url siteUrl
                       }
                   }
               }
           }
       }
       
       //遍历 soursSets，打包源码
       task sourcesJar(type: Jar) {
           from android.sourceSets.main.java.srcDirs
           classifier = 'sources'
       }
       
       task javadoc(type: Javadoc) {
           source = android.sourceSets.main.java.srcDirs
           classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
       }
       task javadocJar(type: Jar, dependsOn: javadoc) {
           classifier = 'javadoc'
           from javadoc.destinationDir
       }
       //输出maven
       artifacts {
           archives javadocJar
           archives sourcesJar
       }
       //读取local.properties中属性，私密属性在本地配置并添加至.gitignore.
       Properties properties = new Properties()
       properties.load(project.rootProject.file('local.properties').newDataInputStream())
       bintray {//你的bintray账号配置,配置正确才能在bintray账号中找到你的包
           user = properties.getProperty("bintray.user")
           key = properties.getProperty("bintray.apikey")
           configurations = ['archives']
           pkg {
               repo = "maven"
               name = "simple"	//发布到JCenter上的项目名字
               websiteUrl = siteUrl
               vcsUrl = gitUrl
               licenses = ["Apache-2.0"]
               publish = true
               publicDownloadNumbers = true
       
           }
       }